3、基本函数和事件

　　 setchartbaseprops函数

　　 如下面的代码所示，setchartbaseprops()函数的作用是设置图表基本属性的默认值。

private sub setchartbaseprops()
  '--- 为组件用户预定义的属性
  with oexcelchart
    .charttype = xl3dcolumnclustered
    .sizewithwindow = true
    .hasdatatable = false
  end with
end sub

　　 该函数由class_intialize事件调用。在这里我们把默认的图表类型设置为三维柱形图。如果sizewithwindow属性没有设置，则图表的大小会超过excel工作表的大小，最终也会超过浏览器窗口的大小。excel图表允许将数值作为一个独立的表格显示，在这里我们通过hasdatatable属性关闭了该功能。

　　 class_initialize事件

　　 class_initialize()完成一些准备工作。

private sub class_initialize()
  '--- 创建excel应用实例
  set oexcelapp = createobject("excel.application")
  '---设置excel应用不可见，然后加入一个工作簿
  oexcelapp.visible = false
  oexcelapp.sheetsinnewworkbook = 1: oexcelapp.workbooks.add
  
  with oexcelapp.activeworkbook
    '--- 获取第一个工作表
    set oexcelsheet = .sheets(1)
    '--- 加入新的图形工作表
    set oexcelchart = .sheets.add(type:=xlchart)
    '--- 设置图表的基本属性
    setchartbaseprops
  end with
end sub

　　 所有基于该类的对象，其初始化过程都会触发这个class_initialize事件。第一行代码的作用是初始化一个excel应用作为activex服务器。用户并不直接访问activex服务器，该服务器仅在内部完成图表绘制工作。excel应用的visible属性设置成了false，这保证了任何情况下用户都不会直接见到excel。

　　 默认情况下excel 2000会将三个空的工作表加入新工作簿。为便于控制，程序把新工作表数量设置成了1，当然必要的时候可以加入新的工作表。接下来程序又将新的工作簿加入到了已经初始化的excel应用。新加入的工作簿将自动成为活动工作簿，因为它是应用中唯一的工作簿。

　　 第一个工作表也是唯一的工作表，该表可以通过工作簿的sheets集合访问，程序把它存储到了全局变量oexcelsheet以便其他方法访问。该表实际上用来存储adddataseries()函数所传递的数据。接下来程序又将一个新的工作表加入到了sheets集合，新表的类型为xlchart。第二个工作表用来存放图表，现在我们把它保存到了全局变量oexcelchart。

　　 综上所述，现在组件中有了下面这些对象：

　　

　　 　　 　　 　　 　　【图2】

　　 class_terminate事件

private sub class_terminate()
  if (not (oexcelapp is nothing)) then
    '--- 检查是否确实存在工作簿
    if (oexcelapp.workbooks.count  > 0) then
      '--- 关闭工作簿，忽略任何修改
      oexcelapp.workbooks(1).close savechanges:=false
    end if
    '--- 退出excel，释放资源
    oexcelapp.quit: set oexcelapp = nothing
  end if
end sub

　　 结束全部工作之后，对象的拆除操作将触发class_terminate事件。class_terminate检查所有已经分配空间的对象并依次释放它们。工作簿对象包含两个工作表，即图表工作表和数据工作表。在绘制图表之后工作表的内容已经改变，因此，close方法的savechanges参数必须指定false以忽略对工作表内容的修改，这样也就避免了每次生成一个图表都要创建一个excel文件（.xls文件）。程序最后调用quit方法退出excel应用并清除对象。