今天整理文件时发现了以前写的货币金额中文转换（转换一亿亿元以下数目的货币）的代码，帖出来与大家共享：
function daxie(money as string) as string '
dim x as string, y as string
const zimu = ".sbqwsbqysbqwsbq" '定义位置代码
const letter = "0123456789sbqwy.zjf" '定义汉字缩写
const upcase = "零壹贰叁肆伍陆柒捌玖拾佰仟萬億圆整角分" '定义大写汉字
dim temp as string
temp = money
if instr(temp, ".") > 0 then temp = left(temp, instr(temp, ".") - 1)
if len(temp) > 16 then msgbox "数目太大，无法换算！请输入一亿亿以下的数字", 64, "错误提示": exit function '只能转换一亿亿元以下数目的货币！
x = format(money, "0.00") '格式化货币
y = ""
for i = 1 to len(x) - 3
y = y & mid(x, i, 1) & mid(zimu, len(x) - 2 - i, 1)
next
if right(x, 3) = ".00" then
y = y & "z" '***元整
else
y = y & left(right(x, 2), 1) & "j" & right(x, 1) & "f" '*元*角*分
end if
y = replace(y, "0q", "0") '避免零千(如：40200肆萬零千零贰佰)
y = replace(y, "0b", "0") '避免零百(如：41000肆萬壹千零佰)
y = replace(y, "0s", "0") '避免零十(如：204贰佰零拾零肆)
do while y <> replace(y, "00", "0")
y = replace(y, "00", "0") '避免双零(如：1004壹仟零零肆)
loop
y = replace(y, "0y", "y") '避免零億(如：210億 贰佰壹十零億)
y = replace(y, "0w", "w") '避免零萬(如：210萬 贰佰壹十零萬)
y = iif(len(x) = 5 and left(y, 1) = "1", right(y, len(y) - 1), y) '避免壹十(如：14壹拾肆；10壹拾)
y = iif(len(x) = 4, replace(y, "0.", ""), replace(y, "0.", ".")) '避免零元(如：20.00贰拾零圆；0.12零圆壹角贰分)
for i = 1 to 19
y = replace(y, mid(letter, i, 1), mid(upcase, i, 1)) '大写汉字
next
daxie = y
end function
private sub command3_click()
debug.print daxie("6218212212309322.3238") ' return: 陆仟贰佰壹拾捌萬贰仟壹佰贰拾贰億壹仟贰佰叁拾萬玖仟叁佰贰拾贰圆叁角贰分
end sub
